# Kapitel 11
#  Grenzwerte von Folgen
# ====================================
# Der Befehl "seq" ist nur f"ur endliche Folgen gut:
> seq(1/k, k=1..infinity);
Error, unable to execute seq
> seq(1/k, k=1..15);
# Verwende zur Beschreibung der Folgenglieder Funktionen oder
# Ausdr"ucke ("expressions").
# Funktionen k"onnen durch die "arrow-notation" definiert werden
# oder durch Programme (--> Kap. 12).
> f:= x->1/x ;
> f(123);f(y);
> limit(f(n), n = infinity);
> Limit(f(x), x = infinity)=limit(f(x), x = infinity);
# =========================================
# Weitere Standardbeispiele, nun unter Verwendung von expressions:
> ?expression
> ?algebraic
> ?arithmetic
> ?limit
> Limit((1+1/n)^n, n=infinity)=limit((1+1/n)^n,
> n=infinity);
> Limit((1+a/n)^n, n=infinity)=limit((1+a/n)^n,
> n=infinity);
> Limit(1/n!, n=infinity)=limit(1/n!,
> n=infinity);
> Limit((4*n^2+2*n-5)/(3*n^2+n+7),n=infinity)=limit((4*n^2+2*n-5)/
> (3*n^2+n+7),n=infinity);
> Limit(sqrt(4*n^2+9*n+1)-2*n,n=infinity)=limit(sqrt(4*n^2+9*n+1)-2*n,n=
> infinity);
> Limit((1-1/n^2)^n,n=infinity)=limit((1-1/n^2)^n,n=infinity);
# Grenzwerte mit Parametern und "assume".
# =============================
> Limit(q^n,n=infinity)=limit(q^n,n=infinity);
> assume(abs(q)<1);
> limit(q^n,n=infinity);
> about(q);
> assume(q,RealRange(Open(-1),Open(1)));
> limit(q^n,n=infinity);
# Es geht auch:
> assume(-1<q,q<1);
> about(q);
# ========================================
# Aufgabe 11.1:
# ==========
# Man bestimme den Grenzwert
#  limit((a^(2*n)-1)/(a^(2*n)+1), n=infinity)  f"ur reelles a . 
# 
# Das Ergebnis wird von a abh"angen.
# Wir wollen Maple dazu verwenden, eine passende Fallunterscheidung
# f"ur a zu finden.
# Dazu berechnen wir einige Testwerte f"ur spezielle a und definieren
# eine Funktion:
# 
> Grenzwert:=a->limit((a^(2*n)-1)/(a^(2*n)+1),n=infinity);
# Testwerte:
> [Grenzwert(1/3),Grenzwert(-1/3),Grenzwert(0.9),Grenzwert(-0.9)];
> [Grenzwert(1),Grenzwert(1.1),Grenzwert(2),Grenzwert(20)];
# Da der Grenzwert offensichtlich eine gerade Funktion von a ist,
# sollten Fallunterscheidung und Ergebnisse lauten:
#       a      |   a>1 |  a=1  | -1<a , a<1 | a=-1 | a<-1
# _____________| ______|______ |____________|______|_______
#   Grenzwert  |  1    |   0   |   -1       |  0   |   1 
#
# Solange a>-1  ist, l"asst sich dies mit Maple auch verifizieren:
> assume(a>1);
> Grenzwert(a);
# Den Fall a=1 haben wir oben schon gesehen. 
> assume(a>-1,a<1);
> Grenzwert(a);
# Wenn man auch die F"alle a=-1 , a<-1 mit Maple zu behandeln versucht,
# gibt es Schwierigkeiten:
> Grenzwert(-1);Grenzwert(-2);
# Also "ubermitteln wir zun"achst unsere Annahmen und verifizieren sie:
> assume(a<-1);
> assume(n,posint);
> about(a);
> about(n);
# Aber das Ergebnis bleibt unbefriedigend:
> Grenzwert(a);

> Grenzwert(-1);
# Notfalls kann man sich helfen, indem man den Quotienten als eine neue
# Funktion F definiert und wenigstens Stichproben berechnet:
> F:=(a,n)->(a^(2*n)-1)/(a^(2*n)+1);
> [F(-1,1),F(-1,2),F(-1,3),F(-1,4),F(-1,5)];
> [F(-1.1,1),F(-1.1,2),F(-1.1,3),F(-1.1,4),F(-1.1,5)];
> [F(-1.1,10),F(-1.1,200),F(-1.1,300)];
# Dies best"atigt unsere Vermutung.
# ==========================================
# Annahmen l"oschen:
> a;n;q;
> a:='a';n:='n';q:='q';
> about(a);about(n);about(q);
# Fazit : Auf die "assume"-Funktion sollte man sich 
# nicht blind verlassen.
# Siehe hierzu auch Kapitel 14 : "Verteiltes Wissen".
# ====================================
# Intervalle als Ergebnisse von "limit":
> limit(cos(Pi*n),n=infinity);
> ?limit
> 
# The output from limit may be a range (meaning a bounded 
# result) or an algebraic expression, possibly containing infinity. For
# further help with the return type see limit[return]. 
# Dort steht:
# If limit returns a numeric range it means that the value of the 
# limiting expression is known to lie in that range for arguments
# restricted to some neighborhood of the limit point. It does not
# necessarily imply that the limiting expression is known to achieve
# every value infinitely often in this range.